MIt der neuen Hardware soll dies alles auf Festplatte erfolgen. Dabei soll weiterhin eine Sicherung aller relevanter Daten täglich erfolgen und die jeweilige Tagessicherung eine Woche lang aufgehoben werden. In Anlehnung an die Skripte, die hier auch im Forum und Wiki zur Verfügung stehen, setzen wir jetzt den nachfolgenden Skript ein, vielleicht ist er ja auch jemanden anderen nützlich. Die Daten werden zunächst in ein Backupverzeichnis kopiert, dann als Zip-Daten mit 7-Zip (Freeware, http://www.7-zip.org/, muss bereits installiert sein) gepackt und unter dem jeweiligen Wochentagsnamen abgelegt. Hier der Skript:
Code: Alles auswählen
@echo off
REM Backupscript für die tägliche Datensicherung
REM by sirky 2011-10-01
REM Sichert täglich inkrementell und hebt die Sicherung zusätzlich
REM jeweils eine Woche auf
REM Pfade sind gegebenfalls anzupassen und 7zip muss installiert sein
REM ------------------------------------------------------------
echo Sichere Turbomed...
REM ------------------------------------------------------------
REM zunächst wird Turbomed in den Backup-Modus versetzt
REM ------------------------------------------------------------
call c:\turbomed\Programm\TMAdmin /beginBackup /server=poweredge
REM ------------------------------------------------------------
REM jetzt per robocopy das turbomed verzeichnis sichern
REM ------------------------------------------------------------
robocopy "C:\turbomed" "C:\backup\turbomed" /MIR /COPY:DAT /V /NP /R:10 /W:30
REM ------------------------------------------------------------
REM danach kann der server wieder in den Standard modus versetzt werden
REM ------------------------------------------------------------
call c:\turbomed\Programm\TMAdmin /endBackup /server=poweredge
echo Fertig mit dem Turbomed-Backup
REM ------------------------------------------------------------
REM weitere wichtige Inhalte des Servers sichern
REM einfach entsprechend alles einfügen, was gesichtert werden soll
REM ------------------------------------------------------------
echo Sichere weitere Daten...
echo Sichere Custo...
robocopy "C:\custo" "C:\backup\custo" /MIR /COPY:DAT /V /NP /R:10 /W:30
echo Fertig mit dem Custo-Backup
REM ------------------------------------------------------------
REM Nach Abschluss das Wochentagsarchiv erstellen und zusammenpacken
REM dazu zunächst aktuellen Wochentag ermitteln
REM ------------------------------------------------------------
REM Hier eventuell Reihenfolge und delims anpassen
FOR /F "tokens=1,2,3 delims=." %%a in ('echo %date%') do set yy=%%c & set mm=%%b & set dd=%%a
set /a "TwoDigitYearMax=2038%%1000"
if 1%yy% LSS 200 if 1%yy% LSS 1%TwoDigitYearMax% (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,dow=153*m+2
set /a dow=dow/5+dd+y*365+y/4-y/100+y/400-2472630,dow%%=7,dow+=1
If %dow% equ 1 set "WoTa=Montag"
If %dow% equ 2 set "WoTa=Dienstag"
If %dow% equ 3 set "WoTa=Mittwoch"
If %dow% equ 4 set "WoTa=Donnerstag"
If %dow% equ 5 set "WoTa=Freitag"
If %dow% equ 6 set "WoTa=Samstag"
If %dow% equ 7 set "WoTa=Sonntag"
echo Heute ist ein %WoTa%
SET BackupFileDestination=c:\backuparchiv\%WoTa%.zip
REM Falls eine Datei der letzten Woche existiert, löschen
IF EXIST "%BackupFileDestination%" DEL /f /q "%BackupFileDestination%"
REM ------------------------------------------------------------
REM jetzt packen und ablegen, dabei wird die letzte Woche überschrieben
REM ------------------------------------------------------------
REM Hier den Pfad anpassen, wenn 7-Zip nicht im Standardordner installiert ist
SET exe7Zip=%ProgramFiles%\7-Zip\7z.exe
START "Komprimierung des Backups für das Wochenarchiv, bitte warten..." /wait "%exe7Zip%" a -tzip -r -mx5 "%BackupFileDestination%" "c:\backup\"
ECHO Fertig mit der Komprimierung.
Echo Kopiere auf externes Laufwerk...
robocopy C:\backup\ E:\backup\ /MIR
robocopy C:\backuparchiv\ E:\backuparchiv\ /MIR
ECHO Für heute ist alles erledigt!